TM1637-display: NTP-klok met ESP8266 of ESP32

Wat heb je nodig?

• Arduino IDE (gratis) — met de ESP8266- en ESP32-board manager URL's ingesteld
• TM1637-display — bijvoorbeeld via Amazon
• WiFiManager-bibliotheek — voor een WiFi-verbinding zonder hard gecodeerd wachtwoord
• TM1637Display-bibliotheek — aansturing van het display
• Een ESP8266 of ESP32 bordje — bv. een goedkoop starter pack
• Soldeerloze verbindingsdraden

TM1637-display + ESP8266

Verbindingen:

ESP8266 -> TM1637
=================
GND --------> GND
3V3 --------> VCC
D2  --------> DIO
D1  --------> CLK

Sketch voor een eenvoudig klokje:

#include <WiFiManager.h>    // https://github.com/tzapu/WiFiManager/
#include <TM1637Display.h>  // https://github.com/avishorp/TM1637/

struct tm tInfo;  // https://cplusplus.com/reference/ctime/tm/
WiFiManager myWiFi;
TM1637Display ledSeg(5, 4);  // scl (clk) -> GPIO5 (D1) / sda (dio) -> GPIO4 (D2).

void setup() {
  Serial.begin(115200);                                           // watch serial monitor in case of new WiFi-connection
  myWiFi.autoConnect("TM1637_ESP");                               // connect ESP to new wifi via GSM or PC in that case
  ledSeg.setBrightness(2);                                        // 0 .. 7
  configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org");  // https://github.com/nayarsystems/posix_tz_db/blob/master/zones.csv
}

void loop() {
  getLocalTime(&tInfo);                                                                           // sntp sync at startup & every hour from then on
  ledSeg.showNumberDecEx(tInfo.tm_hour * 100 + tInfo.tm_min, 0x40 * (millis() % 1000 < 500), 1);  // 0x40 = ":", 1 = leading zeros
}

• schakelt automatisch over op zomer- of wintertijd
• synchroniseert 1 keer per uur met SNTP-server
• kan met elke WiFi verbinden zonder aanpassing van de code (instelbaar met bvb. GSM)
• geen "hard gecodeerd" paswoord
• slechts 18 lijnen code
• geen delay()-opdrachten

Hoe werkt het?

• #include <WiFiManager.h> — bibliotheek om de ESP met de WiFi te verbinden, inclusief webserver als de WiFi-gegevens niet eerder ingebracht waren. De verbinding kan overal. Als de verbinding niet lukt, dan zie je op de seriële monitor:
  • *wm:StartAP with SSID: TM1637_ESP
  • *wm:AP IP address: 192.168.4.1
  • *wm:Starting Web Portal
• Je moet met je GSM of tablet of PC verbinden met dit access point, een browser starten en als adres 192.168.4.1 ingeven, en je kan de WiFi-gegevens ingeven. Voordeel is dat je de ESP kan verplaatsen naar elders (of een WiFi-toegangspunt wijzigen) zonder dat je opnieuw de code moet compileren. Ook zonder serial monitor zal je merken als het klokje niet werkt: dan moet je ook via het access point verbinden en de WiFi-gegevens inbrengen. Eenmaal het klokje gestart is kan je de WiFi-verbinding verbreken, het klokje zal gewoon verder lopen (uiteraard zonder synchronisatie dan).
• De laatste lijnen van de functies "setup" en "loop" zijn krachtig, ze voeren veel uit op 1 lijn:
  • configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org"); — dit is de lijn die er voor zorgt dat de juiste tijdzone gebruikt wordt, het klokje zich automatisch aanpast aan zomer- of wintertijd, en vervolgens aangeeft met welke NTP-servers je wenst te synchroniseren.
  • ledSeg.showNumberDecEx(ti.tm_hour * 100 + ti.tm_min, 0x40 * (millis() % 1000 < 500), 1); — de tijd wordt op het display weergegeven met een dubbelpunt dat elke halve seconde verborgen of getoond wordt, en met vooroplopende nullen.
• getLocalTime(&timeinfo); vraagt de tijd uit de ESP8266 op, aangepast volgens tijdzone en zomertijd/wintertijd. De eerste keer wordt er gesynchroniseerd met de NTP-server, de volgende keren gebeurt de synchronisatie om het uur (werd uitgebreid getest met callbackfuncties). Om het uur betekent niet "telkens wanneer het uur verspringt", wel telkens een uur na de vorige synchronisatie.
• Er is geen interval ingesteld voor de synchronisatie met SNTP. Standaard staat dat interval op 1 uur (ESP8266), dat is ruimschoots voldoende om de correcte tijd te verkrijgen. Update wintertijd/zomertijd gebeurt ook zonder synchronisatie. De update via NTP gebeurt namelijk steeds in UTC-tijd, nooit in lokale tijd — en het is de lokale tijd die de zomertijd of wintertijd aanstuurt.

TM1637-display + ESP32

Volgende code voor ons "minimumklokje" is aangepast voor zowel de ESP8266 als de ESP32. Het standaard interval voor de tijdsynchronisatie voor de ESP32 is 3 uur, voor de ESP8266 is dat 1 uur. De enige aanpassingen zijn de GPIO-aansluitingen van het display:

Verbindingen:

ESP32 ---> TM1637
=================
GND --------> GND
3V3 --------> VCC
G21 --------> DIO
G22 --------> CLK

Sketch:

#include <WiFiManager.h>    // https://github.com/tzapu/WiFiManager/
#include <TM1637Display.h>  // https://github.com/avishorp/TM1637/

struct tm tInfo;  // https://cplusplus.com/reference/ctime/tm/
WiFiManager myWiFi;
#if defined(ESP32)  
TM1637Display ledSeg(22, 21);  // scl (clk) -> G22 / sda (dio) -> G21.
#elif defined(ESP8266)
TM1637Display ledSeg(5, 4);  // scl (clk) -> GPIO5 (D1) / sda (dio) -> GPIO4 (D2).
#endif

void setup() {
  Serial.begin(115200);                                           // watch serial monitor in case of new WiFi-connection
  myWiFi.autoConnect("TM1637_ESP");                               // connect ESP to new wifi via GSM or PC in that case
  ledSeg.setBrightness(2);                                        // 0 .. 7
  configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org");  // https://github.com/nayarsystems/posix_tz_db/blob/master/zones.csv
}

void loop() {
  getLocalTime(&tInfo);                                                                           // sntp sync at startup & every hour from then on
  ledSeg.showNumberDecEx(tInfo.tm_hour * 100 + tInfo.tm_min, 0x40 * (millis() % 1000 < 500), 1);  // 0x40 = ":", 1 = leading zeros
}

We zouden deze code kunnen uitbreiden, zodat het klokje, als het een WiFi-verbinding aangaat tijdens de opstart, zelf zijn locatie opzoekt via een API. Dan kan de tijdzone automatisch toegekend worden. Zo zou je een NTP-klokje kunnen maken met de ESP, dat je om het even waar ter wereld kan gebruiken. Na het verbinden met een beschikbare WiFi geeft het de correcte locale tijd weer.

Meer displays met de ESP8266 / ESP32

Benieuwd naar andere displays? Bekijk het volledige overzicht met o.a. SSD1306, SH1106, ST7735, ST7789, e-paper en geïntegreerde displays zoals de Lilygo T-Display en de Waveshare ESP32-S3.